在Asp中如何迅速優(yōu)化分頁的技巧

foxty [原作]

    近日一直在研究如何才能寫出高小的分頁算法，大概整理了一下，思路如下：
 
    首先數(shù)據(jù)庫里需要有一個(gè)自動(dòng)編號(hào)字段（ID）。然后第一次訪問的時(shí)候，取出所有記錄，定制好每頁的記錄數(shù)PageSize，計(jì)算出頁數(shù)，然后根據(jù)頁數(shù)建立一個(gè)一維數(shù)組PageId(PageCount)，PageId(0)保存記錄初試條件，然后對(duì)應(yīng)每個(gè)元素保存每頁對(duì)應(yīng)的ID邊界碼
（
  1，ID邊界碼：如果數(shù)據(jù)庫記錄ID記錄序列如下  1，2，3，4，5，6，7，8，9，10，11，12，13，14，15，16
  假設(shè)需要按照ID 順序排序的話 ，PageSize = 5, Pagecount = 4 ，PageId(4)
   數(shù)組PageId的值分別為PageId(0) = 1, PageId(1) = 5 ,PageId(2) = 10,PageId(3) = 15 ,PageId(4) = 16
   當(dāng)訪問第 i 頁的時(shí)候就直接找 [PageId(i-1) , PageId(i) ) 之間的記錄，這樣可以保證每次取的記錄都只是PageSize 條記錄。
  假設(shè)需要按照ID倒序排列的話,
   數(shù)組PageId的值分別為PageId(0) = 16 , PageId(1) = 12 , PageId(2) = 7 ,PageId(3) = 2, PageId(4) = 1, 當(dāng)訪問第 i 頁的時(shí)候就直接查找ID屬于[ PageId(i-1) , PageId(i) ) 

）
 將數(shù)組PageId()保存在Application()中，以便訪問，這樣，只是第一次訪問分頁程序的時(shí)候便初始化Application()。代碼部分如下:（下面稱為新程序）

<%
 Time1 = Timer()
 Dim Conn
 Set Conn = Server.CreateObject("Adodb.Connection")
 Conn.open "Driver={MicroSoft Access Driver (*.mdb)};Dbq="&Server.MapPath("db.mdb")
 'www.knowsky.com
 Dim Page,PageCounts,PageId,PageList
 Dim Rs,Sql
 Dim IsInit,i
 
 IsInit   = False                                         '標(biāo)志為，用來判斷Application("PageId")是否初始化
 PageList = 20                                            '設(shè)置每頁顯示20條數(shù)據(jù)
 Set Rs    = Server.CreateObject("Adodb.Recordset")
 Page     = Request.QueryString("Page")                         '注意頁碼需要檢查類型
 
 If IsEmpty(Application("PageId")) Then               '如果Application("PageId")還未初始化,則先進(jìn)行初始化
  Response.Write("Init app!<br>")
  Sql      = "Select * From test Order By Id Desc"  '假定這里是按照ID倒序排列
  Rs.open Sql,Conn,1,1  '得到記錄集對(duì)象
 
  If Not (Rs.Eof  or Rs.Bof) Then
   Rs.PageSize = PageList                        '設(shè)置每頁記錄數(shù)
   PageCounts  = Rs.PageCount
   ReDim PageId(PageCounts)                      '重新定義數(shù)組PageId
   For i = 0 To PageCounts                       '開始給數(shù)組 PageId() 賦值   
    If Rs.eof Then Exit For
    PageId(i) = Rs("ID")
    Rs.Move (PageList)
   Next
   Rs.MoveLast
   PageId(PageCounts) = Rs("ID")
   Application.Lock()
   Application("PageId") = PageId
   Application.UnLock() 
  End If
  Rs.Close
 End If
 IdStart = Clng(Application("PageId")(Page-1))
 IdEnd   = Clng(Application("PageId")(Page))
 Sql = "Select * from test where id<="&IdStart&" and id>"&IdEnd&" "
 Rs.open Sql,Conn,1,1
 While Not Rs.eof
  Response.Write(rs(0)&"--"&rs(1))
  Rs.MoveNext
 Wend
 Rs.Close 
 Set Rs = Nothing
 Conn.Close
 Set Conn = Nothing
 
 
 For i = 1 To Ubound(Application("PageId"))
  Response.Write("<a href='Test1.asp?Page="&i&"'>"&i&"</a>　")
 Next
 Time2 = Timer()
 
 Response.Write("<br>"&(Time2-Time1)*1000)
 'Application.Contents.Remove("PageId")
%>

傳統(tǒng)分頁代碼如下:（下面稱為舊程序）
<%
 Time1 = Timer()
 Dim Conn
 Set Conn = Server.CreateObject("Adodb.Connection")
 Conn.open "Driver={MicroSoft Access Driver (*.mdb)};Dbq="&Server.MapPath("db.mdb")
 
 Dim Page,PageCounts,PageList
 Dim Rs,Sql
 
 PageList = 20
 Page     = Request.QueryString( "Page" )
 Set Rs   = Server.CreateObject("Adodb.Recordset")
 Sql      = "Select * from test order by id desc"
 Rs.Open Sql,Conn,1,1
 
 If Page = "" Then Page = 1
 If Not( Rs.eof Or Rs.Bof ) Then
  Rs.PageSize     = PageList
  PageCounts      = Rs.PageCount
  Rs.AbsolutePage = Page 
 End If
 
 For i = 1 to PageList
  If Rs.eof Then Exit For
  Response.Write(Rs(0)&"-----"&Rs(1)&"<br>")
  Rs.MoveNext
 next
 
 For i = 1 To PageCounts
  Response.Write("<a href='Test.asp?Page="&i&"'>"&i&"</a>　")
 Next
 Time2 = Timer()
 
 Response.Write("<br>"&(Time2-Time1)*1000)
%>
 
    其實(shí)，總體的思想就是，建立一個(gè)Application("PageId")全局?jǐn)?shù)組,每個(gè)元素都保存頁面所區(qū)記錄的ID區(qū)間，比如，Application("PageId")(0) 保存第一個(gè)元素的ID，然后Application("PageId")(1)保存下一頁的第一個(gè)ID…………依次類推，當(dāng)需要訪問第 i 頁的時(shí)候，就直接查找ID在 [ Application("PageId")(i-1)  , Application("i") ) 里面的記錄集，這樣，每次只用查找需要的記錄數(shù)，而不需要每次都把所有記錄都查找一遍，但是，這個(gè)方法是在第一次訪問的時(shí)候，即需要?jiǎng)?chuàng)建數(shù)組Application("PageId")的時(shí)候比較慢一點(diǎn)，當(dāng)?shù)贜次訪問的時(shí)候 （N>1）速度就快將近10倍，我采用上面2個(gè)程序測(cè)試：
  1，數(shù)據(jù)庫記錄有32000條記錄，舊程序訪問一頁需要500毫秒左右，新程序只是第一次訪問的時(shí)候達(dá)到這個(gè)時(shí)間，然后每次都只需要55毫秒左右。
  2，將數(shù)據(jù)增加到64000條記錄，舊程序訪問一頁需要1000毫秒左右，新程序也是第一次訪問的時(shí)候達(dá)到這個(gè)似乎件， 后面每次仍然還是保持在55毫秒左右。
  3，將數(shù)據(jù)增加到128000條記錄，舊程序訪問一頁需要1900毫秒左右，新程序第一次訪問需要2300毫秒左右，然后每次訪問只需要70毫秒左右。
  這里需要注意的是數(shù)據(jù)庫每改動(dòng)一次，Application("PageId") 就需要重新賦值!

    研究心得：（首先謝謝葉子(DVBBS)的心得）盡量不要用自帶的分頁程序，Rs.RecordCount 很耗資源。依次，估計(jì)Rs.PageCount ……也耗資源，而且用Rs.GetRows()效果也很明顯提高。
 
    經(jīng)過比較，葉子的算法在記錄比較靠前的時(shí)候速度以及效率是比較高的。但是不太穩(wěn)定，有時(shí)（很少）會(huì)從30毫秒左右跳到1-200毫秒。到了后面效率就明顯下降到50-80毫秒，越后效率越低。新算法第一次效率比較低下，大約在500毫秒左右，但是比較穩(wěn)定，后面一般哦度是50毫秒左右，而且隨著庫的記錄數(shù)變化，這個(gè)速度依然如此。不會(huì)有什么變化。下次就把葉子和我的算法結(jié)合起來試試，不過葉子的算法確實(shí)是很不錯(cuò)D，具備通用性。我這個(gè)只能拿來聊聊了。