使用模板完成ASP代碼與頁面分離
發(fā)表時(shí)間：2024-02-06 來源：明輝站整理相關(guān)軟件相關(guān)文章人氣：
[摘要]文章出處:編程手札 http://blog.csdn.net/nhconch 請(qǐng)大家多多支持. 每個(gè)進(jìn)行過較大型的ASP-Web應(yīng)用程序設(shè)計(jì)的開發(fā)人員大概都有如下的經(jīng)歷：ASP代碼與頁面HTML混淆難分，業(yè)務(wù)邏輯與顯示方式絞合，使得代碼難以理解、難以修改；程序編寫必須在美工之后，成為項(xiàng)目瓶頸；整...
文章出處:編程手札
http://blog.csdn.net/nhconch 請(qǐng)大家多多支持.
每個(gè)進(jìn)行過較大型的ASP-Web應(yīng)用程序設(shè)計(jì)的開發(fā)人員大概都有如下的經(jīng)歷：ASP代碼與頁面HTML混淆難分，業(yè)務(wù)邏輯與顯示方式絞合，使得代碼難以理解、難以修改；程序編寫必須在美工之后，成為項(xiàng)目瓶頸；整合的程序代碼和HTML靜態(tài)頁面時(shí)，花費(fèi)大量的時(shí)間才能得到理想的效果，兼作了美工。的確，用腳本語言開發(fā)Web應(yīng)用不容易將數(shù)據(jù)的處理和數(shù)據(jù)的顯示分開，但在多人合作的情況下，如果無法將數(shù)據(jù)和顯示分開，將大大影響開發(fā)的效率，專業(yè)分工的發(fā)揮。
其它的腳本語言，如JSP、PHP都有自己的解決方案，ASP的后一代產(chǎn)品ASP.NET也實(shí)現(xiàn)了代碼與頁面，似乎直接過渡到ASP是不錯(cuò)的選擇。但是總有這樣或那樣的原因讓我們不能或暫時(shí)不能放棄ASP直奔.NET大營。從公司角度來看，轉(zhuǎn)換語言是一筆不少的投資，包括雇傭熟手.NET程序員、培訓(xùn)原有程序員、開發(fā)工具的轉(zhuǎn)型、開發(fā)風(fēng)格的轉(zhuǎn)型、界面風(fēng)格轉(zhuǎn)變、接口風(fēng)格、軟件架構(gòu)、文檔、開發(fā)流程等等；這還意味著原有的代碼必須在新語言環(huán)境里重寫以實(shí)現(xiàn)最佳的效果和穩(wěn)定性；同時(shí)將直接影響這段時(shí)間內(nèi)項(xiàng)目的進(jìn)度，更有可能導(dǎo)致個(gè)別程序員出走。由此看來在您決定轉(zhuǎn)換語言之前，在原基礎(chǔ)上尋求一種解決方案，才是最好的選擇。
PHP通過模板實(shí)現(xiàn)代碼與頁面，可供選擇的有FastTemplate、PHPLIB、Smarty等多種，其中PHPLIB的影響最大、使用最多。既然如此，我們直接把它搬到ASP來，對(duì)于同時(shí)使用PHP和ASP的公司還有很有好處：一、美工處理頁面時(shí)，不管將要套用PHP還是ASP，處理方式是一樣，無須經(jīng)過培訓(xùn)；二、程序員編寫代碼時(shí)，兩種語言間的思路接近或一致，相同功能在兩種語言實(shí)現(xiàn)時(shí)，只需拷貝過來略作修改即可，保證了工作效率和項(xiàng)目進(jìn)度。
1、模板類的設(shè)計(jì)
實(shí)現(xiàn)代碼封裝成為模板類，即是為了與PHPLIB兼容，也使得代碼方便管理與擴(kuò)展。
模板類要實(shí)現(xiàn)的目標(biāo)為：從模板文件中讀入顯示的HTML代碼，將這些顯示代碼中需要?jiǎng)討B(tài)數(shù)據(jù)的地方替換為ASP程序運(yùn)算所得出的數(shù)據(jù)，然后按照一定的順序輸出。其中，替換的部分可以自由的設(shè)定。因此它必須完成如下任務(wù)：
·從模板文件中讀取顯示用的HTML代碼。
·將模板文件和實(shí)際生成的數(shù)據(jù)結(jié)合，生成輸出的結(jié)果。
·允許同時(shí)處理多個(gè)模板。
·允許模板的嵌套。
·允許對(duì)模板中的某個(gè)單獨(dú)的部分進(jìn)行處理。
實(shí)現(xiàn)方法：
采用FSO讀取模板文件
采用正則替換實(shí)現(xiàn)模板文件和數(shù)據(jù)的結(jié)合
處理多個(gè)模板用數(shù)組存儲(chǔ)來實(shí)現(xiàn)。
模板的嵌套的實(shí)現(xiàn)主要的想法是：將模板和輸出（任何中間的分析結(jié)果）一視同仁，都可拿來做替換，即可實(shí)現(xiàn)。
單獨(dú)部分的處理的通過在模板文件中設(shè)定標(biāo)注，然后在正則替換中結(jié)合標(biāo)注來控制，實(shí)現(xiàn)部分替換。
2、模板類的實(shí)現(xiàn)
給出具體代碼之前，先把主要函數(shù)列出，用過PHPLIB的朋友應(yīng)該對(duì)此很熟悉了：
1）Public Sub set_root(ByVal Value) 設(shè)定模板默認(rèn)目錄
2）Public Sub set_file(ByVal handle,ByVal filename) 讀取文件
3）Public Sub set_var(ByVal Name, ByVal Value, ByVal Append) 設(shè)置映射數(shù)據(jù)-替換變量
4）Public Sub unset_var(ByVal Name) 取消數(shù)據(jù)映射
5）Public Sub set_block(ByVal Parent, ByVal BlockTag, ByVal Name) 設(shè)置數(shù)據(jù)塊
6）Public Sub set_unknowns(ByVal unknowns) 設(shè)定未指定映射的標(biāo)記處理方式
7）Public Sub parse(ByVal Name, ByVal BlockTag, ByVal Append) 執(zhí)行模板文件與數(shù)據(jù)的結(jié)合
8）Public Sub p(ByVal Name) 輸出處理結(jié)果
實(shí)現(xiàn)代碼：
<%
'=======================================================================
' 本對(duì)象中使用了set_var、set_block等命名方法是為了兼容phplib
'=======================================================================
'www.knowsky.com
Class kktTemplate
Private m_FileName, m_Root, m_Unknowns, m_LastError, m_HaltOnErr
Private m_ValueList, m_BlockList
Private m_RegExp
' 構(gòu)造函數(shù)
Private Sub Class_Initialize
Set m_ValueList = CreateObject("Scripting.Dictionary")
Set m_BlockList = CreateObject("Scripting.Dictionary")
set m_RegExp = New RegExp
m_RegExp.IgnoreCase = True
m_RegExp.Global = True
m_FileName = ""
m_Root = ""
m_Unknowns = "remove"
m_LastError = ""
m_HaltOnErr = true
End Sub
' 析構(gòu)函數(shù)
Private Sub Class_Terminate
Set m_RegExp = Nothing
Set m_BlockMatches = Nothing
Set m_ValueMatches = nothing
End Sub
Public Property Get ClassName()
ClassName = "kktTemplate"
End Property
Public Property Get Version()
Version = "1.0"
End Property
Public Sub About()
Response.Write("kktTemplate ASP頁面模板類<br>" & vbCrLf &_
"程序設(shè)計(jì)：彭國輝 2004-07-05<br>" & vbCrLf &_
"個(gè)人網(wǎng)站：<a & vbCrLf &_
"電子郵件：<a href='mailto:kacarton@sohu.com'>kacarton@sohu.com</a><br>")
End Sub
'檢查目錄是否存在
Public Function FolderExist(ByVal path)
Dim fso
Set fso = CreateObject("Scripting.FileSystemObject")
FolderExist = fso.FolderExists(Server.MapPath(path))
Set fso = Nothing
End Function
'讀取文件內(nèi)容
Private Function LoadFile()
Dim Filename, fso, hndFile
Filename = m_Root
If Right(Filename, 1)<>"/" And Right(Filename, 1)<>"\" Then Filename = Filename & "/"
Filename = Server.MapPath(Filename & m_FileName)
Set fso = CreateObject("Scripting.FileSystemObject")
If Not fso.FileExists(Filename) Then ShowError("模板文件" & m_FileName & "不存在!")
set hndFile = fso.OpenTextFile(Filename)
LoadFile = hndFile.ReadAll
Set hndFile = Nothing
Set fso = Nothing
If LoadFile = "" Then ShowError("不能讀取模板文件" & m_FileName & "或文件為空!")
End Function
'處理錯(cuò)誤信息
Private Sub ShowError(ByVal msg)
m_LastError = msg
Response.Write "<font color=red style='font-size;14px'><b>模板錯(cuò)誤：" & msg & "</b></font><br>"
If m_HaltOnErr Then Response.End
End Sub
'設(shè)置模板文件默認(rèn)目錄
'Ex: kktTemplate.set_root("/tmplate")
' kktTemplate.Root = "/tmplate"
' root = kktTemplate.get_root()
' root = kktTemplate.Root
'使用類似set_root這樣的命名方法是為了兼容phplib，以下將不再重復(fù)說明
Public Sub set_root(ByVal Value)
If Not FolderExist(Value) Then ShowError(Value & "不是有效目錄或目錄不存在!")
m_Root = Value
End Sub
Public Function get_root()
get_root = m_Root
End Function
Public Property Let Root(ByVal Value)
set_root(Value)
End Property
Public Property Get Root()
Root = m_Root
End Property
'設(shè)置模板文件
'Ex: kktTemplate.set_file("hndTpl", "index.htm")
'本類不支持多模板文件，handle為兼容phplib而保留
Public Sub set_file(ByVal handle,ByVal filename)
m_FileName = filename
m_BlockList.Add Handle, LoadFile()
End Sub
Public Function get_file()
get_file = m_FileName
End Function
' Public Property Let File(handle, filename)
' set_file handle, filename
' End Property
' Public Property Get File()
' File = m_FileName
' End Property
'設(shè)置對(duì)未指定的標(biāo)記的處理方式，有keep、remove、comment三種
Public Sub set_unknowns(ByVal unknowns)
m_Unknowns = unknowns
End Sub
Public Function get_unknowns()
get_unknowns = m_Unknowns
End Function
Public Property Let Unknowns(ByVal unknown)
m_Unknowns = unknown
End Property
Public Property Get Unknowns()
Unknowns = m_Unknowns
End Property
Public Sub set_block(ByVal Parent, ByVal BlockTag, ByVal Name)
Dim Matches
m_RegExp.Pattern = "<!--\s+BEGIN " & BlockTag & "\s+-->([\s\S.]*)<!--\s+END " & BlockTag & "\s+-->"
If Not m_BlockList.Exists(Parent) Then ShowError("未指定的塊標(biāo)記" & Parent)
set Matches = m_RegExp.Execute(m_BlockList.Item(Parent))
For Each Match In Matches
m_BlockList.Add BlockTag, Match.SubMatches(0)
m_BlockList.Item(Parent) = Replace(m_BlockList.Item(Parent), Match.Value, "{" & Name & "}")
Next
set Matches = nothing
End Sub
Public Sub set_var(ByVal Name, ByVal Value, ByVal Append)
Dim Val
If IsNull(Value) Then Val = "" Else Val = Value
If m_ValueList.Exists(Name) Then
If Append Then m_ValueList.Item(Name) = m_ValueList.Item(Name) & Val _
Else m_ValueList.Item(Name) = Val
Else
m_ValueList.Add Name, Value
End If
End Sub
Public Sub unset_var(ByVal Name)
If m_ValueList.Exists(Name) Then m_ValueList.Remove(Name)
End Sub
Private Function InstanceValue(ByVal BlockTag)
Dim keys, i
InstanceValue = m_BlockList.Item(BlockTag)
keys = m_ValueList.Keys
For i=0 To m_ValueList.Count-1
InstanceValue = Replace(InstanceValue, "{" & keys(i) & "}", m_ValueList.Item(keys(i)))
Next
End Function
Public Sub parse(ByVal Name, ByVal BlockTag, ByVal Append)
If Not m_BlockList.Exists(BlockTag) Then ShowError("未指定的 塊標(biāo)記" & Parent)
If m_ValueList.Exists(Name) Then
If Append Then m_ValueList.Item(Name) = m_ValueList.Item(Name) & InstanceValue(BlockTag) _
Else m_ValueList.Item(Name) = InstanceValue(BlockTag)
Else
m_ValueList.Add Name, InstanceValue(BlockTag)
End If
End Sub
Private Function finish(ByVal content)
Select Case m_Unknowns
Case "keep" finish = content
Case "remove"
m_RegExp.Pattern = "\{[^ \t\r\n}]+\}"
finish = m_RegExp.Replace(content, "")
Case "comment"
m_RegExp.Pattern = "\{([^ \t\r\n}]+)\}"
finish = m_RegExp.Replace(content, "<!-- Template Variable $1 undefined -->")
Case Else finish = content
End Select
End Function
Public Sub p(ByVal Name)
If Not m_ValueList.Exists(Name) Then ShowError("不存在的標(biāo)記" & Name)
Response.Write(finish(m_ValueList.Item(Name)))
End Sub
End Class
%>
3、使用例子
下面舉三個(gè)例子進(jìn)行說明。
1)簡單的值替換
模板文件為myTemple.tpl，內(nèi)容：
<html><title>ASP模板簡單替換</title><body>
祝賀！你贏了一輛{some_color}法拉利！
</body>
下面是ASP代碼（kktTemplate.inc.asp就是上面給出的模板類）：
<!--#INCLUDE VIRTUAL="kktTemplate.inc.asp"-->
<%
dim my_color, kkt
my_color = "紅色的"
set kkt = new kktTemplate '創(chuàng)建模板對(duì)象
kkt.set_file "hndKktTemp", "myTemple.tpl" '設(shè)置并讀取模板文件myTemple.tpl
kkt.set_var "some_color", my_color, false '設(shè)置模板變量 some_color = my_color的值
kkt.parse "out", "hndKktTemp", false '模板變量 out = 處理后的文件
kkt.p "out" '輸出out的內(nèi)容
set kkt = nothing '銷毀模板對(duì)象
%>
執(zhí)行后輸出為：
<html><title>ASP模板簡單替換</title><body>
祝賀！你贏了一輛紅色的法拉利！
</body>
2)循環(huán)塊演示例子
模板文件myTemple2.tpl：
<html><title>ASP模板－塊的演示</title><body>
<table cellspacing="2" border="1"><tr><td>下面的動(dòng)物您喜歡哪一種</td></tr>
<!-- BEGIN AnimalList -->
<tr><td><input type="radio" name="chk">{animal}</td></tr>
<!-- END AnimalList -->
</table>
</body>
ASP代碼：
<!--#INCLUDE VIRTUAL="kktTemplate.inc.asp"-->
<%
dim animal, kkt, i
animal = Array("小豬","小狗","小強(qiáng)")
set kkt = new kktTemplate
kkt.set_file "hndKktTemp", "myTemple2.tpl"
kkt.set_block "hndKktTemp", "AnimalList", "list"
for i=0 to UBound(animal)
kkt.set_var "animal", animal(i), false
kkt.parse "list", "AnimalList", true
next
kkt.parse "out", "hndKktTemp", false
kkt.p "out"
set kkt = nothing
%>
執(zhí)行結(jié)果：
<html><title>ASP模板－塊的演示</title><body>
<table cellspacing="2" border="1"><tr><td>下面的動(dòng)物您喜歡哪一種</td></tr>
<tr><td><input type="radio" name="chk">小豬</td></tr>
<tr><td><input type="radio" name="chk">小狗</td></tr>
<tr><td><input type="radio" name="chk">小強(qiáng)</td></tr>
</table>
</body>
3)嵌套塊演示
模板文件myTemple3.tpl：
<html><title>ASP模板－嵌套塊演示</title>
<body><table width="400" border="1" bordercolor="#000000">
<tr><td><div align="center">{myname}測試</div></td></tr>
<tr><td>我的動(dòng)植物園：</td> </tr>
<!-- BEGIN animalList -->
<tr><td>{animal}</td></tr>
<!-- BEGIN plantList -->
<tr><td> {plant}</td></tr>
<!-- END plantList -->
<!-- END animalList -->
</table>
</body>
</html>
ASP代碼：
<!--#INCLUDE VIRTUAL="kktTemplate.inc.asp"-->
<%
dim my_color, kkt, myname, animal, plant
set kkt = new kktTemplate
myname = "kktTemplate block test..."
animal = array("動(dòng)物", "植物")
plant = array(array("小豬","小白","小強(qiáng)"), array("玫瑰","向日葵"))
kkt.set_file "hndKktTemp", "myTemple3.tpl"
kkt.set_var "myname", myname, false
kkt.set_block "hndKktTemp", "animalList", "a"
kkt.set_block "animalList", "plantList", "p"
for i=0 to UBound(animal)
kkt.set_var "animal", animal(i), False
kkt.unset_var "p"
'kkt.set_var "p", "", false
for j=0 to UBound(plant(i))
kkt.set_var "plant", plant(i)(j), false
kkt.parse "p", "plantList", true
next
kkt.parse "a", "animalList", true
next
kkt.parse "out", "hndKktTemp", false
kkt.p "out"
%>
執(zhí)行結(jié)果：
<html><title>ASP模板－嵌套塊演示</title>
<body><table width="400" border="1" bordercolor="#000000">
<tr><td><div align="center">kktTemplate block test...測試</div></td></tr>
<tr><td>我的動(dòng)植物園：</td> </tr>
<tr><td>動(dòng)物</td></tr>
<tr><td> 小豬</td></tr>
<tr><td> 小白</td></tr>
<tr><td> 小強(qiáng)</td></tr>
<tr><td>植物</td></tr>
<tr><td> 玫瑰</td></tr>
<tr><td> 向日葵</td></tr>
</table>
</body>
</html>
本文提及的所有代碼可從此處下載：http://www.freewebs.com/kacarton/web/kktTemplate.rar
4、小結(jié)
本文主要介紹了基于ASP利用模板類實(shí)現(xiàn)代碼與頁面分離的方法，當(dāng)然還有其它更好的解決方案。本文旨在拋磚引玉各位讀者、WEB開發(fā)參與進(jìn)來，多提寶貴意見，多作交流，共同進(jìn)步！
