曾經(jīng)在網(wǎng)上看到有人說(shuō)Delphi能夠產(chǎn)生大小只有16k的Win32應(yīng)用程序，而我自己曾經(jīng)編寫(xiě)過(guò)的這種可執(zhí)行文件大小則是在17k左右，因而我一度猜想Delphi恐怕也只能將代碼優(yōu)化到這種程度了。最近由于測(cè)試的目的重新把這個(gè)程序?qū)懥艘槐�，才發(fā)現(xiàn)利用一些技巧，還能夠?qū)⑽募�的大小進(jìn)一步縮減到8.5k。這個(gè)程序也能夠顯示Delphi作為類(lèi)似于Visual C++的、非RAD工具的另一個(gè)側(cè)面。如果你對(duì)此感興趣的話，請(qǐng)看我是如何做到這一點(diǎn)的。



用Delphi生成一個(gè)默認(rèn)的項(xiàng)目，然后用工具欄上的Remove file from Project按鈕，將唯一的窗體(Form1)從項(xiàng)目中刪除。然后選擇View->Project Source命令，打開(kāi)項(xiàng)目文件，并編輯代碼如下所示：

program MiniApp;



uses

  Windows, Messages;



// {$R *.res}



const

  szAppName : PChar = 'MiniApp';



function WndProc(AWnd:HWND; message:UINT; wp:WPARAM; lp:LPARAM):LRESULT;stdcall;

begin

  Result := 0;

  case message of

    WM_DESTROY:

       PostQuitMessage(0);

    else

       Result := DefWindowProc(AWnd, message, wp, lp);

  end;

end;



var

  wc : WNDCLASS;

  HMainWnd : HWND;

  AMsg : MSG;



begin

  with wc do begin

    style := CS_VREDRAW or CS_HREDRAW;

    lpfnWndProc := @WndProc;

    cbClsExtra := 0;

    cbWndExtra := 0;

    hIcon := LoadIcon(0, IDI_APPLICATION);

    hCursor := LoadCursor(0, IDC_ARROW);

    hbrBackground := GetSysColorBrush(COLOR_WINDOW);

    hInstance := HInstance;

    lpszMenuName := nil;

    lpszClassName := szAppName;

  end;

  RegisterClass(wc);



  HMainWnd := CreateWindow(szAppName,

                           szAppName,

                           WS_OVERLAPPEDWINDOW,

                           Integer(CW_USEDEFAULT), Integer(CW_USEDEFAULT),

                           Integer(CW_USEDEFAULT), Integer(CW_USEDEFAULT),

                           HWND_DESKTOP, 0,

                           HInstance, nil);

  ShowWindow(HMainWnd, CmdShow);

  UpdateWindow(HMainWnd);



  while GetMessage(AMsg, 0, 0, 0) do begin

    TranslateMessage(AMsg);

    DispatchMessage(AMsg);

  end;

end.



其實(shí)這些代碼根本就是Win32 SDK中C語(yǔ)言例子程序的翻版，我想沒(méi)有必要再對(duì)它們作什么解釋了。需要提醒你注意的是：

1．Delphi程序沒(méi)有像C程序那樣的WinMain入口，程序的運(yùn)行就從.DPR文件的begin開(kāi)始，到與之匹配的end結(jié)束。而C程序中傳遞給WinMain的四個(gè)參數(shù)，在Delphi中則以全局變量的形式定義在System以及SysInit單元中，它們分別是HInstance、HPrevInst、CmdLine和CmdShow（HPrevInst已經(jīng)沒(méi)有意義）。

2．注意我把常量szAppName定義為PChar，而不是常用的String，因?yàn)樵谶@么一個(gè)簡(jiǎn)單的程序中沒(méi)有必要使用String的高級(jí)功能，這樣可以節(jié)省不少空間（大約3-4k）。

3．我把{$R *.res}一句也注釋起來(lái)了，這樣可以從文件中剔除冗余的資源，從而節(jié)省大約1k左右的空間。

4．程序完成后，打開(kāi)Project Options對(duì)話框，翻到Compiler頁(yè)，將Runtime Errors和Debugging分類(lèi)中的選項(xiàng)全部清除，這樣也可以稍微減小最終文件的大小。



盡管還不能說(shuō)8.5k一定就是最小的尺寸，不過(guò)我猜想這已經(jīng)非常接近Delphi的極限了。在Visual C++中，很有意思的一點(diǎn)是所有可執(zhí)行文件的大小都會(huì)對(duì)齊到4k的邊界，所以在Visual C++中最小的.EXE和最小的.DLL大小都只能達(dá)到28k，除非使用一些非常特殊的隱藏編譯開(kāi)關(guān)。盡管Win32中的分頁(yè)默認(rèn)是4k，不過(guò)我實(shí)在想不通Visual C++把可執(zhí)行文件的大小也對(duì)齊到4k究竟有什么意義？

另外，我手頭還有一套非常非常古老的Turbo Pascal for Windows 1.5，它所編譯出的最小的Windows可執(zhí)行文件的大小——你肯定無(wú)法相信——只有1.75k！當(dāng)然了，它畢竟只是個(gè)Win16程序而已。