轉(zhuǎn)讓控制權(quán)，以便讓操作系統(tǒng)處理其它的事件。

DoEvents 函數(shù)會(huì)返回一個(gè) Integer，以代表 Visual Basic 獨(dú)立版本中打開(kāi)的窗體數(shù)目，例如，Visual Basic，專業(yè)版，在其它的應(yīng)用程序中，DoEvents 返回 0。

DoEvents 會(huì)將控制權(quán)傳給操作系統(tǒng)。當(dāng)操作系統(tǒng)處理完隊(duì)列中的事件，并且在 SendKeys 隊(duì)列中的所有鍵也都已送出之后，返回控制權(quán)。

DoEvents 對(duì)于簡(jiǎn)化諸如允許用戶取消一個(gè)已啟動(dòng)的過(guò)程 — 例如搜尋一個(gè)文件 — 特別有用。對(duì)于長(zhǎng)時(shí)間過(guò)程，放棄控制權(quán)最好使用定時(shí)器或通過(guò)委派任務(wù)給 ActiveX EXE 部件來(lái)完成。以后，任務(wù)還是完全獨(dú)立于應(yīng)用程序，多任務(wù)及時(shí)間片由操作系統(tǒng)來(lái)處理。

小心 確保以 DoEvents 放棄控制權(quán)的過(guò)程，在第一次 DoEvents 返回之前，不能再次被其他部分的代碼調(diào)用；否則會(huì)產(chǎn)生不可預(yù)料的結(jié)果。此外，如果其它的應(yīng)用程序可能會(huì)和本過(guò)程以不可預(yù)知的方式進(jìn)行交互操作，那么也不要使用 DoEvents，因?yàn)榇藭r(shí)不能放棄控制權(quán)。

使用 DoEvents

盡管 Timer 事件是后臺(tái)處理的最好工具，對(duì)耗時(shí)極多的任務(wù)，情況更是如此，但是，DoEvents 函數(shù)還是提供了一種取消任務(wù)的簡(jiǎn)便方法。例如，下列代碼將顯示一個(gè) "Process" 按鈕，單擊這個(gè)按鈕時(shí)，它將變成 "Cancel" 按鈕。再次單擊按鈕又將中斷正在執(zhí)行的任務(wù)。

'此按鈕標(biāo)題是 "Process"
Private Sub Command1_Click()
'過(guò)程的所有實(shí)例都共享靜態(tài)變量。
  Static blnProcessing As Boolean
  Dim lngCt As Long
  Dim intYieldCt As Integer
  Dim dblDummy As Double
  '按下按鈕時(shí)，檢測(cè)是否在處理
  If blnProcessing Then
   '如果正在處理，則取消
      blnProcessing = False
  Else
      Command1.Caption = "Cancel"
      blnProcessing = True
      lngCt = 0
   '執(zhí)行一百萬(wàn)次浮點(diǎn)乘法計(jì)算。每一千次后，檢測(cè)是否要取消。
      Do While blnProcessing And (lngCt < 1000000)
        For intYieldCt = 1 To 1000
            lngCt = lngCt + 1
            dblDummy = lngCt * 3.14159
        Next intYieldCt
      'DoEvents 語(yǔ)句允許其它事件發(fā)生，包括第二次按此按鈕。
        DoEvents
      Loop
      blnProcessing = False
      Command1.Caption = "Process"
      MsgBox lngCt & " multiplications were performed"
  End If
End Sub

DoEvents 將控制切換到操作環(huán)境內(nèi)核。只要此環(huán)境中的所有應(yīng)用程序都有機(jī)會(huì)響應(yīng)待處理事件，應(yīng)用程序就又恢復(fù)控制。這不會(huì)使應(yīng)用程序放棄焦點(diǎn)，但會(huì)使后臺(tái)事件能夠得到處理。

這種妥協(xié)的結(jié)果可能并不總是達(dá)到預(yù)期目標(biāo)。例如，下述 Click 事件代碼在單擊按鈕后要一直等候十秒鐘，而后才顯示一條信息。如果在按鈕正在等待期間單擊它，則將以相反順序完成單擊操作。

Private Sub Command2_Click()
  Static intClick As Integer
  Dim intClickNumber As Integer
  Dim dblEndTime As Double
      '每次單擊按鈕時(shí)
      '賦予唯一數(shù)值。
  intClick = intClick + 1
  intClickNumber = intClick
      '等待十秒。
  dblEndTime = Timer + 10#
  Do While dblEndTime > Timer
      '不做任何事情，僅僅允許
      '其它應(yīng)用程序處理
      '它們的事件。
      DoEvents
  Loop
  MsgBox "Click " & intClickNumber & " is finished"
End Sub

對(duì)于通過(guò) DoEvents 放棄控制的事件過(guò)程，有時(shí)可能希望防止在 DoEvents 返回之前重新調(diào)用這一過(guò)程。否則將無(wú)窮無(wú)盡地調(diào)用該過(guò)程，直到系統(tǒng)資源消耗殆盡。可暫時(shí)禁止控件，或象上例一樣，使用一個(gè)靜態(tài)的“標(biāo)志”變量防止此事發(fā)生。

在使用全局?jǐn)?shù)據(jù)時(shí)避免 DoEvents
當(dāng)一個(gè)函數(shù)已通過(guò) DoEvents 放棄控制時(shí)，可相當(dāng)安全地再次調(diào)用函數(shù)。例如，下一過(guò)程將檢測(cè)質(zhì)數(shù)并用 DoEvents 語(yǔ)句周期地啟動(dòng)其它應(yīng)用程序處理事件：

Function PrimeStatus (TestVal As Long) As Integer
  Dim Lim As Integer
  PrimeStatus = True
  Lim = Sqr(TestVal)
  For I = 2 To Lim
      If TestVal Mod I = 0 Then
        PrimeStatus = False
        Exit For
      End If
      If I Mod 200 = 0 Then DoEvents
  Next I
End Function

該代碼中每重復(fù) 200 次就調(diào)用一次 DoEvents 語(yǔ)句。這樣一來(lái)，當(dāng)該環(huán)境的其余部分對(duì)事件作出響應(yīng)時(shí)，只要有必要，PrimeStatus 過(guò)程就可繼續(xù)計(jì)算。

考慮在調(diào)用 DoEvents 期間發(fā)生的事情。在其它窗體和應(yīng)用程序處理事件時(shí)將暫停執(zhí)行應(yīng)用程序代碼。這些事件之一有可能是一個(gè)按鈕單擊操作，它將再次啟動(dòng) PrimeStatus 過(guò)程。

這將導(dǎo)致重新進(jìn)入 PrimeStatus 過(guò)程的，但是，因?yàn)樵诤瘮?shù)每次出現(xiàn)時(shí)，堆棧都為其參數(shù)和局部變量分配了空間，所以重入不會(huì)引發(fā)沖突。當(dāng)然，如果過(guò)多調(diào)用 PrimeStatus，則可能出現(xiàn)“溢出堆�？臻g”錯(cuò)誤。

如果 PrimeStatus 使用或改變模塊級(jí)變量或全局?jǐn)?shù)據(jù)，情況就會(huì)完全不同。此時(shí)，在 DoEvents 能夠返回之前執(zhí)行 PrimeStatus 的另一個(gè)實(shí)例，這將導(dǎo)致模塊數(shù)據(jù)或全局?jǐn)?shù)據(jù)的值完全不同于它們?cè)谡{(diào)用 DoEvents 之前的值。于是，PrimeStatus 的結(jié)果將會(huì)難以預(yù)料。


       以上代碼來(lái)自： 源代碼數(shù)據(jù)庫(kù)(SourceDataBase)
           當(dāng)前版本： 1.0.392
               作者： Shawls
           個(gè)人主頁(yè)： Http://Shawls.Yeah.Net
             E-Mail： ShawFile@163.Net
                 QQ： 9181729